! =========================================
! Shen-Yeh Chen
! 05/01/1998
! =========================================
! This macro will get/plot (reponse vs load level) graph on the creen
! Using this macor is similar to use the *GET command like
!   *GET,_Parname,_Entity,_EntityID,_Item,_Comp
! For example, if you issue the following command
!   x_plsbst,      , _BgnLdSet,_EndLdSet,'NODE',100,'U','X'
! The macro will do the following internally
!   *GET,X_PLLDST(_LdSet,1),NODE,100,U,X
! The index _LdSet will go through the loop from loadset number _BgnLdSet to _EndLdSet
! The time step ratio will be stored in the "0" column of the matrix X_PLLDST
! The value get for each time step will be stored in the "1" column of the matrix X_PLLDST
! And the table data will be written into the file x_plldst.csv  
! --------------------------------------------------------------------------   
!
! Syntax :
!   x_plsbst,      , _BgnLdSet,_EndLdSet,'_Entity',_EntityID,'_Item','_Comp'
!
! Input :
!   _BgnLdSet : Beginning load set ID
!   _End      : End load set ID
!   '_Entity',_EntityID,'_Item','_Comp'
!             : see ANSYS manual for *GET,_Parname,_Entity,_EntityID,_Item,_Comp
! 
! Output :
!   file : x_plldst.csv
!
! Example
!     x_plsbst,      , _BgnLdSet,_EndLdSet,'NODE',_NodeID,'U','X'
!     x_plsbst,      ,1,5,'NODE',100,'S','EQV'
!             : plot/get time vs equivalent stress for node ID 100
!
! External programs called :
!  None
! =========================================
AR31=ARG3-ARG2+1
*GET,AR61,PARM,X_PLSBST,TYPE
*IF,AR61,NE,2,THEN
 *DIM,X_PLLDST,table,AR31+1,1
*ENDIF
!
!
AR21=ARG4
AR22=ARG5
AR23=ARG6
AR24=ARG7
!
/POST1
AR32=1
AR41=0.0
X_PLLDST(1,0)=0.0
X_PLLDST(1,1)=0.0
*DO,AR33,ARG2,ARG3,1
 SET,AR33
 AR32=AR32+1
 *GET,AR42,ACTIVE,0,SOLU,DTIME
 AR41=AR41+AR42
 X_PLLDST(AR32,0)=AR41
 *GET,X_PLLDST(AR32,1),%AR21%,AR22,%AR23%,%AR24%
*ENDDO
/XRANGE,0,AR41
*VPLOT,X_PLLDST(1,0),X_PLLDST(1,1)
!
*CFOPEN,x_plsbst,csv
*VWRITE,X_PLLDST(1,0),X_PLLDST(1,1)
(1P,1X,E15.6,',',1X,E15.6)
*CFOPEN